home *** CD-ROM | disk | FTP | other *** search
/ The Game Master (3rd Edition) / The Game Master 3rd edition.iso / files / educames / spelling / spell.bas < prev    next >
BASIC Source File  |  1983-10-16  |  8KB  |  263 lines
  1. 10 KEY OFF:CLS
  2. 20 SCREEN 0
  3. 30 WIDTH 40
  4. 40 PRINT"░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░"
  5. 50 PRINT"░┌───────────────────────────────────┐░"
  6. 60 PRINT"░│                                   │░"
  7. 70 PRINT"              5019-A.BAS               "
  8. 80 PRINT"                 SPELL                 "
  9. 90 PRINT"                                       "
  10. 100 PRINT"                                       "
  11. 110 PRINT"░│ BROUGHT TO YOU BY THE MEMBERS OF  │░"
  12. 120 PRINT"░│      ▄▄▄▄▄ ▄▄▄▄▄ ▄▄▄▄▄ ▄▄▄▄▄      │░"
  13. 130 PRINT"░│        █   █   █ █     █   █      │░"
  14. 140 PRINT"░│        █   █▄▄▄█ █     █   █      │░"
  15. 150 PRINT"░│        █   █     █     █   █      │░"
  16. 160 PRINT"░│      ▄▄█▄▄ █     █▄▄▄▄ █▄▄▄█      │░"
  17. 170 PRINT"░│                                   │░"
  18. 180 PRINT"░│      International PC Owners      │░"
  19. 190 PRINT"░│                                   │░"
  20. 200 PRINT"░│P.O. Box 10426, Pittsburgh PA 15234│░"
  21. 210 PRINT"░│                                   │░"
  22. 220 PRINT"░└───────────────────────────────────┘░"
  23. 230 PRINT"░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░"
  24. 240 PRINT
  25. 250 PRINT "       PRESS ANY KEY TO CONTINUE
  26. 260 A$=INKEY$: IF A$="" THEN 260
  27. 270 WIDTH 80
  28. 280 CLS
  29. 1000 'This program is a program that I
  30. 1010 '
  31. 1020 'found in a very good book called
  32. 1030 '
  33. 1040 '100 Ready-To-Run Programs &
  34. 1050 '
  35. 1060 'Subroutines For The I.B.M. P.C.
  36. 1070 '
  37. 1080 'by Jeff Bretz & John Clark Craig
  38. 1090 '
  39. 1100 'I then took the Dolch Word List
  40. 1110 '
  41. 1120 'and added to the program.
  42. 1130 '
  43. 1140 'The Dolch list has been the
  44. 1150 '
  45. 1160 'standard list of the basic words
  46. 1170 '
  47. 1180 'a child should be able to sight
  48. 1190 '
  49. 1200 'read for many years.
  50. 1210 '
  51. 1220 'I also added several other
  52. 1230 '
  53. 1240 'things to make the program
  54. 1250 '
  55. 1260 'more interasting.
  56. 1270 '
  57. 1280 '
  58. 1290 'I hope you find this program as
  59. 1300 '
  60. 1310 'useful as I have.
  61. 1320 '
  62. 1330 'If you have any ideas on how to
  63. 1340 '
  64. 1350 'inprove this program, or you
  65. 1360 '
  66. 1370 'have an educational program of
  67. 1380 '
  68. 1390 'your own, please send it to me
  69. 1400 '
  70. 1410 'Robert West, 655 S. Chubb Dr.
  71. 1420 '
  72. 1430 'Doylestown, Pa. 18901
  73. 1440 '
  74. 1450 'Thanks
  75. 2000  REM         SPELL
  76. 2010 CLEAR
  77. 2020 SCREEN 1
  78. 2030 COLOR 0,0
  79. 2040 KEY OFF
  80. 2050 CLS
  81. 2060 LOCATE 10,19
  82. 2070 PRINT "SPELL
  83. 2080 FOR DELTA = 3 TO 77 STEP 5
  84. 2090 LINE (120-DELTA,70-DELTA)-(205+DELTA,80+DELTA),,B
  85. 2100 NEXT DELTA
  86. 2110 BEEP:LOCATE 23,7:INPUT "WHAT IS YOUR NAME ";NAM$
  87. 2120 GOSUB 3240
  88. 2130 LOCATE 23,7:BEEP:INPUT "WHAT LIST WOULD YOU LIKE 1-37";L
  89. 2140 LOCATE 23,7:PRINT "                                 "
  90. 2150 LOCATE 23,7:BEEP:INPUT "HOW MANY WORDS 1-10";C
  91. 2160 DIM A$(C),SCORE(C),TH$(400)
  92. 2170 FOR X =1 TO (L-1)*10
  93. 2180 READ TH$
  94. 2190 NEXT X
  95. 2200 FOR I = 1 TO C
  96. 2210 SCORE(I) = 2
  97. 2220 NEXT I
  98. 2230 CLS
  99. 2240 COLOR 0,1
  100. 2250 FOR I = 1 TO C
  101. 2260 READ CAP$
  102. 2270 A$(I) = CAP$
  103. 2280 NEXT I
  104. 2290 CLS
  105. 2300 COLOR 0,0
  106. 2310 S=LEN(NAM$)
  107. 2320 R=(S/2)
  108. 2330 PRINT TAB(8-R)"THESE ARE YOUR WORDS ";NAM$
  109. 2340 PRINT :PRINT
  110. 2350 FOR I=1 TO C
  111. 2360 PRINT A$(I),
  112. 2370 NEXT I
  113. 2380 FOR I=1 TO 5000:NEXT I
  114. 2390 CLS
  115. 2400 LET Z$ =TIME$
  116. 2410 LET F$=MID$(Z$,7,2)
  117. 2420 LET Z=VAL (F$)
  118. 2430 RANDOMIZE (Z)
  119. 2440 PTR = INT(RND*C+1)
  120. 2450 J = 0
  121. 2460 IF SCORE(PTR) THEN 2520
  122. 2470 PTR = PTR MOD C + 1
  123. 2480 J = J+1
  124. 2490 IF J > C THEN 3110
  125. 2500 GOTO 2460
  126. 2510 '
  127. 2520 CLS
  128. 2530 COLOR 0,1
  129. 2540 LOCATE 13,20 - LEN(A$(PTR)) / 2
  130. 2550 PRINT A$(PTR);
  131. 2560 FOR I = 9 TO 99 STEP 3
  132. 2570 LINE (0,99-I)-(319,99-I),2
  133. 2580 LINE (0,99+I)-(319,99+I),2
  134. 2590 NEXT I
  135. 2600 IF SCORE(PTR) = 2 THEN GOSUB 3360
  136. 2610 CLS
  137. 2620 COLOR 0,1
  138. 2630 LOCATE 9,7
  139. 2640 PRINT "NOW TRY TO SPELL IT ...
  140. 2650 LOCATE 14,17 - LEN(A$(PTR)) /2:SOUND 2000,1
  141. 2660 IF LEN(INKEY$) THEN 2660
  142. 2670 INPUT CAP$
  143. 2680 IF CAP$ = A$(PTR) THEN 2860
  144. 2690 '
  145. 2700 ' WHOOPS, BETTER LUCK NEXT TIME
  146. 2710 CLS
  147. 2720 LOCATE 14,9
  148. 2730 SOUND 50,5
  149. 2740 PRINT "SORRY ......    ";A$(PTR);
  150. 2750 LOCATE 16,17
  151. 2760 INPUT CAP$
  152. 2770 IF CAP$ <> A$(PTR) THEN GOTO 2710
  153. 2780 CLS:LOCATE 14,9:PRINT "NOW SPELL IT...."
  154. 2790 LOCATE 16,17
  155. 2800 INPUT CAP$
  156. 2810 IF CAP$ <> A$(PTR) THEN GOTO 2710
  157. 2820 SCORE(PTR) =2
  158. 2830 GOTO 2390
  159. 2840 '
  160. 2850 'WOW, SIT BACK AND ENJOY SUCESS FOR A SPELL
  161. 2860 CLS
  162. 2870 COLOR 0,0
  163. 2880 LOCATE 12,14:SOUND 300,3
  164. 2890 H=INT(RND*5+1)
  165. 2900 ON H GOTO 2910,2920,2930,2940,2950
  166. 2910 PRINT "  VERY GOOD ":GOTO 2960
  167. 2920 PRINT "THAT'S RIGHT":GOTO 2960
  168. 2930 PRINT "   SMARTY ":GOTO 2960
  169. 2940 PRINT "    GREAT":GOTO 2960
  170. 2950 PRINT "   GENIUS":GOTO 2960
  171. 2960 '
  172. 2970 LOCATE 14,20-R:PRINT NAM$;"!
  173. 2980 FOR I = 33 TO 123 STEP 5
  174. 2990 X1 = 160 - 3 * I
  175. 3000 X2 = 160 + 3 * I
  176. 3010 Y1 = 99 - I
  177. 3020 Y2 = 99 + I
  178. 3030 LINE (X1,99)-(160,Y1)
  179. 3040 LINE - (X2,99)
  180. 3050 LINE - (160,Y2)
  181. 3060 LINE -(X1,99)
  182. 3070 NEXT I
  183. 3080 SCORE(PTR) = SCORE(PTR) - 1
  184. 3090 GOTO 2390
  185. 3100 '
  186. 3110 CLS
  187. 3120 LOCATE 1,1
  188. 3130 PRINT "YOU DID IT! NOW YOU KNOW HOW TO SPELL
  189. 3140 PRINT "ALL THESE WORDS...",,,,,
  190. 3150 FOR I = 1 TO C
  191. 3160 PRINT A$(I),
  192. 3170 NEXT I
  193. 3180 PRINT
  194. 3190 PRINT
  195. 3200 PRINT TAB(11)"CONGRATULATIONS !!
  196. 3210 PRINT TAB(11)STRING$(17,"_");
  197. 3220 LOCATE 22
  198. 3230 END
  199. 3240 ' CHANGE LITTLE LETTERS TO CAPITALS
  200. 3250 FOR CH = 1 TO LEN(NAM$)
  201. 3260 CH$=MID$(NAM$,CH,1)
  202. 3270 FT = ASC(CH$)
  203. 3280 IF FT<96 THEN GOTO 3340
  204. 3290 IF FT>123 THEN GOTO 3340
  205. 3300 FT=FT-32
  206. 3310 CH$=CHR$(FT)
  207. 3320 MID$(NAM$,CH,1)=CHR$(ASC(CH$))
  208. 3330 NEXT CH
  209. 3340 RETURN
  210. 3350 'SUBROUTINE, DELAY FOR AWHILE'''''
  211. 3360 FOR DELAY = 1 TO 777
  212. 3370 NEXT DELAY
  213. 3380 RETURN
  214. 3390 DATA little,down,go,here,it
  215. 3400 DATA big,a,come,funny,help
  216. 3410 DATA jump,in,and,is,I
  217. 3420 DATA blue,for,away,can,find
  218. 3430 DATA you,red,the,to,where
  219. 3440 DATA my,look,play,see,three
  220. 3450 DATA two,we,yellow,up,make
  221. 3460 DATA not,said,me,one,run
  222. 3470 DATA went,no,they,good,came,she,ate,be,but,all,saw
  223. 3480 DATA now,please,ran,with,what,so,get,into,news,am,saw
  224. 3490 DATA,at,black,did,on,white,do,like,under,too,who
  225. 3500 DATA that,say,there,out,pretty,will,this,was,eat,he
  226. 3510 DATA ride,yes,are,brown,four,must,well,have,soon,our
  227. 3520 DATA flower,night,top,car,game,paper,toy,cat,garden,party
  228. 3530 REM nouns
  229. 3540 DATA now,please,ran,with,what,so,get,into,news,am
  230. 3550 DATA,at,black,did,on,white,do,like,under,too,who
  231. 3560 DATA table,bread,fish,name,thing,brother,floor,nest,time,cake
  232. 3570 REM nouns
  233. 3580 DATA,saw,want,apple,day,home,school,baby,dog,horse,seed
  234. 3590 DATA back,doll,house,sheep,ball,door,kitty,shoe,bear,duck
  235. 3600 REM grade 1
  236. 3610 DATA know,after,every,an,going,him,live,could,of,again
  237. 3620 DATA thank,just,them,had,put,once,fly,has,how,any
  238. 3630 DATA give,walk,let,open,old,take,think,ask,may,over
  239. 3640 DATA round,her,were,then,some,by,from,stop,when,his
  240. 3650 '   nouns
  241. 3660 DATA as,kitty,shoe,bear,duck,leg,sister,bed,egg,letter
  242. 3670 DATA snow,bell,eye,man,song,bird,farm,men,squirrel,birthday
  243. 3680 '   grade 2
  244. 3690 DATA sleep,don't,first,read,been,write,around,does,goes,its
  245. 3700 DATA your,many,wish,because,buy,cold,call,made,very,found
  246. 3710 DATA tell,their,why,best,use,these,right,off,always,sit
  247. 3720 DATA wash,green,would,five,work,gave,or,sing,us,fast
  248. 3730 DATA which,both,upon,befor,those,pull,farmer,milk,stick,boat
  249. 3740 '   more nouns also 4 in top line
  250. 3750 DATA tree,chair,girl,picture,watch,chicken,good-by,pig,water,children
  251. 3760 DATA father,money,street,box,feet,morning,sun,boy,fire,mother
  252. 3770 '   grade 3
  253. 3780 DATA carry,draw,clean,fall,if,together,laugh,much,cut,about
  254. 3790 DATA hold,got,bring,hot,kind,long,done,eight,hurt,keep
  255. 3800 DATA snow,light,myself,seven,grow,today,better,full,never,only
  256. 3810 DATA own,six,shall,ten,start,warm,pick,drink,far,try
  257. 3820 '  more nouns
  258. 3830 DATA flower,night,top,car,game,paper,toy,cat,garden,party
  259. 3840 DATA tree,chair,girl,picture,watch,chicken,good-by,pig,water,children
  260. 3850 DATA grass,rabbit,way,christmas,ground,rain,wind,coat,hand,ring
  261. 3860 DATA window,corn,head,robin,wood,cow,hill,Santa Claus,squirrel,school
  262. 3870 DATA little,down,go,here,it
  263.